пиксельшейдер тормоз! [решено] (3 стр)

float4 PSBump(
   float2 TexCoord: TEXCOORD0, 
   float3 Norm : TEXCOORD1, 
   float3 View : COLOR0, 
   float3 Tangent   : TEXCOORD2, 
   float3 Binormal  : TEXCOORD3, 
   float4 PosV      : TEXCOORD4,
   float4 vPosLight : TEXCOORD5) : COLOR
{     

  float LightAmount=PCSS(vPosLight,g_samShadow); //calculate shadow
  //transposed TBN matrix  
  float3x3 tbnMatrix = float3x3(Tangent.x, Tangent.y, Tangent.z,
                                Binormal.x, Binormal.y, Binormal.z,
                                Norm.x, Norm.y, Norm.z);  
  
  float2 ntexcoord;
  float3 fViewDir = normalize(expand(View));
  if (bParallax == true)
    {
        float height = tex2D(bumpSampler, TexCoord).a; // height in alpha channel of normal map!!!        
        height = height * scaleBias.x + scaleBias.y;
        ntexcoord = TexCoord + (height * fViewDir.xy);
    }
  else
    {
        ntexcoord = TexCoord;
    }   
  float4 textureColor = tex2D(textureSampler, ntexcoord);
  textureColor.a = 1;  
  float3 Normal = normalize(mul(tex2D(bumpSampler, ntexcoord).rgb * 2.0f - 1.0f,tbnMatrix)); //move normal to world
  
  float4 mspec = MaterialSpecular;
  mspec.w = 1.0;    
  float3 ViewDir = normalize(expand(View));
  float4 difftemp;
  float4 diff;
  float3 LightDir;
  float4 specular; 
  
  // main light
  LightDir = -normalize(lhtDir.xyz);
  //LightDir = mul(LightDir,tbnMatrix);
  float3 halfv = normalize(LightDir + ViewDir);  
  float nDotL = saturate(dot(Normal, LightDir));
  float nDotH = saturate(dot(Normal, halfv));
  float power = (nDotL == 0.0f) ? 0.0f : pow(nDotH, MaterialSpecular.w);  
  difftemp = nDotL*lightDiffuse*LightAmount; // diffuse component    
  specular = power*difftemp; 
  diff = difftemp;   
  
//additional lights
  for(int i = 0; i < MAX_LIGHTS-1; i++){
   float4 LP = LightsPos[i];
   float4 LD = LightsDif[i];
   float3 Dir = LP.xyz - PosV.xyz;   
   float llen = length(Dir);   
   //Dir = mul(Dir,tbnMatrix);
   float attenuation =  saturate(1.0/(LD.w * llen + LP.w * llen * llen));
   Dir = Dir / llen;
   difftemp = float4(max(dot(Normal, Dir),0)*LD.xyz*attenuation,1.0); // diffuse component
   halfv = normalize(Dir + ViewDir);
   specular += pow(max(0,dot(Normal, halfv)),MaterialSpecular.w)*difftemp;
   diff += difftemp;   
  }  
    
  return saturate(MaterialAmbient + (MaterialDiffuse * diff) + (specular * mspec)) * textureColor;
}