Diligent Engine - современная кросс-платформенная низкоуровневая графическая библиотека (33 стр)

//PS_WaterFull()
Texture2D  texBaseMap1 : register (t0);  // Water noise
Texture2D  texBaseMap2 : register (t1);  // Depth map texture (view space)
Texture2D  texBaseMap3 : register (t2);  // Reflection texture
Texture2D  texBaseMap4 : register (t3);  // Refraction texture
Texture2D  texBaseMap5 : register (t4);  // Water deep
Texture2D  texBaseMap6 : register (t5);  // Foam texture
Texture2D  texShadowMap : register (t6);  // ShadowMaps
//PS_WaterFull()
float4 main(  float4 Position    : SV_POSITION,
        float4 TWave    : TEXCOORD0,
        float4 ProjCoord  : TEXCOORD1,
        float3 WorldPos    : TEXCOORD2,
        float3 TexCoord_Z  : TEXCOORD3,
        float4 FogValue    : TEXCOORD4  ) : SV_TARGET
{
  float2 ProjTC=ProjCoord.xy*float2(0.5f,-0.5f)/ProjCoord.w+float2(0.5f,0.5f);
  /////////////////////////////////////////////////
  // Sample noise texture
  float3 Color1=texBaseMap1.Sample(sampLinear,TWave.xy).rgb;
  float3 Color2=texBaseMap1.Sample(sampLinear,TWave.zw).rgb;
  float3 Bump=Color1+Color2-1;
  float3 Norm=normalize(Bump.xzy);
  /////////////////////////////////////////////////
  // Get pixel depth & get Refraction factor & texture
  float  CurSceneDepth=GetWorldDepth(texBaseMap2.Sample(sampLinear_ClampUV,ProjTC).r);
  if (CurSceneDepth<TexCoord_Z.z) discard;
  float  MainDeepFactor=1-exp(WaterExpDeepFactor*(CurSceneDepth-TexCoord_Z.z));
  float2 DistTC=Norm.xz*MainDeepFactor/ProjCoord.w*0.5f;

  float  NewSceneDepth=GetWorldDepth(texBaseMap2.Sample(sampLinear_ClampUV,ProjTC+DistTC).r);
  if (NewSceneDepth<TexCoord_Z.z) DistTC=float2(0,0);
  else
  {  MainDeepFactor=1-exp(WaterExpDeepFactor*(NewSceneDepth-TexCoord_Z.z));
    DistTC=Norm.xz*MainDeepFactor/ProjCoord.w*0.5f;    }
  /////////////////////////////////////////////////
  // Sample Reflection & Refraction texture
  float3 Reflection=texBaseMap3.Sample(sampLinear_ClampUV,ProjTC+float2(Norm.x*0.1f-0.0125f,0)).rgb*WaterMainColor.rgb;
  float3 Refraction=lerp(texBaseMap4.Sample(sampLinear_ClampUV,ProjTC+DistTC).rgb,WaterDeepColor.rgb,MainDeepFactor);
  /////////////////////////////////////////////////
  float3 ViewVec=normalize(EyePos.xyz-WorldPos);
  float3 HalfVec=normalize(ViewVec-DirLight_Dir.xyz);
  /////////////////////////////////////////////////
  // Get specular component
  float3 R=max(0,dot(HalfVec,Norm));
  float3 Spec=MatSpecular.rgb*(R/(128-R*128+R));
  /////////////////////////////////////////////////
  // Get result Refraction/Reflection
  float  fMix=(1.f-dot(ViewVec,Norm))*MainDeepFactor;
  float3 Result=lerp(Refraction,Reflection,fMix)+Spec*MainDeepFactor;
  /////////////////////////////////////////////////
  // Calculate Foam factor & sample foam texture
  float4 WaterDeepMap=texBaseMap5.Sample(sampLinear_ClampUV,TexCoord_Z.xy);
  float  WaterDeep=WaterDeepMap.r*WaterAltitude;
  float  FoamOffset=WaterDeepMap.a;
  float  FoamPow=1-min(1,(WaterAltitude-WaterDeep)/8.f);
  float  FoamAlpha=max(0,frac((-vecTime.x+FoamPow*30+FoamOffset*10+Norm.x*5)/10.f));
  FoamAlpha=FoamAlpha*FoamAlpha;
  float  FoamPowFade=FoamPow-max(0,FoamPow*1.25f-1)*4;
  FoamPow=min(1,FoamPow*2)*FoamPowFade;
  float  FoamAlphaFade=FoamAlpha-max(0,FoamAlpha*1.125f-1)*8;
  FoamAlpha=FoamAlpha*FoamAlphaFade*max(0.f,Norm.x*10.f);
  float4 FoamColor1=texBaseMap6.Sample(sampLinear,TWave.xy*20.f+Norm.xz*0.1f)*0.6f*WaterMainColor;
  float4 FoamColor2=texBaseMap6.Sample(sampLinear,TWave.zw*20.f-Norm.xz*0.1f)*0.6f*WaterMainColor;
  float4 FoamColor=(FoamColor1+FoamColor2)*DayPower;
  FoamColor.a=min(1.f,(FoamColor.r+FoamColor.g+FoamColor.b)*0.4f)*FoamAlpha*FoamPow;
  Result=lerp(Result,FoamColor.rgb,FoamColor.a);
  /////////////////////////////////////////////////
  // Get shadow factor
  const int ShadowMapsCount=ShadowMapsNum;
  WorldPos.xz+=Norm.xz;
  float ShadBlend=0.f,PDist=distance(WorldPos.xyz,EyePos.xyz),PrevPow=1.f;
  float2 CmpOffs[4]={ float2(0.f,0.f),float2(0.5f,0.f),float2(0.f,0.5f),float2(0.5f,0.5f) };
  [unroll(4)] for (int i=0;i<ShadowMapsCount;i++)
  {  float4 ShadowMapVec=mul(float4(WorldPos,1),matShadowWVP);
    float Shadowed=0.f;
    if (ShadowMapVec.x>=0.f && ShadowMapVec.x<=1.f && ShadowMapVec.y>=0.f && ShadowMapVec.y<=1.f && ShadowMapVec.z>=0.f && ShadowMapVec.z<=1.f)
    Shadowed=1-texShadowMap.SampleCmpLevelZero(sampLinear_ShadowMap,CmpOffs.xy+ShadowMapVec.xy*0.5f,ShadowMapVec.z);
    float ShadPow=saturate(1-(PDist*ShadowParam.y-ShadowParam.x))*PrevPow;
    ShadBlend+=Shadowed*ShadPow;
    PrevPow=max(0.f,1-ShadBlend);  }
  /////////////////////////////////////////////////
  float AltAlpha=min(1,(WaterAltitude-WaterDeep)/4.f);
  Result=Result*(1.f-ShadBlend*ShadowPower*0.5f*AltAlpha);
  /////////////////////////////////////////////////
  // Return Result
  return float4(lerp(Result,FogValue.rgb,FogValue.a),MainDeepFactor*20.f);
}