Стандартные инструменты для конвертации массива png в dds volume texture (2 стр)

program DDSArr;

{$mode objfpc}{$H+}

uses
  {$IFDEF UNIX}{$IFDEF UseCThreads}
  cthreads,
  {$ENDIF}{$ENDIF}
  SysUtils,
  Classes, vampyreimagingpackage,
  ImagingTypes, Imaging, ImagingDDS;

procedure TryAddImage(const AFileName: string; var Arr: TDynImageDataArray);
var img: TImageData;
begin
  InitImage(img);
  if not LoadImageFromFile(AFileName, img) then Exit;
  if Length(Arr) > 0 then
  begin
    if Arr[0].Width <> img.Width then Exit;
    if Arr[0].Height <> img.Height then Exit;
    if Arr[0].Format <> img.Format then Exit;
  end;
  SetLength(Arr, Length(Arr)+1);
  Arr[Length(Arr)-1] := img;
end;

procedure DoWork;
var sr: TSearchRec;
    newDDS: TDynImageDataArray;
    dds: TDDSFileFormat;
begin
  newDDS := nil;
  if FindFirst('*.png', faAnyFile, sr) = 0 then
  begin
    repeat
      if (sr.Attr and faDirectory) <> 0 then Continue;
      TryAddImage(sr.Name, newDDS);
    until FindNext(sr) <> 0;
    FindClose(sr);
  end;
  if Length(newDDS) > 0 then
  begin
    dds := TDDSFileFormat.Create();
    try
      dds.SaveVolume := True;
      dds.SaveDepth := Length(newDDS);
      dds.SaveMipMapCount := 1;
      dds.SaveToFile('total.dds', newDDS);
    finally
      FreeAndNil(dds);
    end;
  end;
end;

begin
  DoWork;
end.