VirtualDub фильтры

local  fps = 25, Sleep = 0, start_hh = 23, start_mm = 59, show_hh = 0, show_mm = 0;
local  Refresh_max = fps * 70;    // Задержка до общего обновления буфера фона
local  Refresh_cnt = Refresh_max;  // Счётчик задержки до общего обновления буфера фона
local  Useful_max = fps * 12;     // Задержка до экономии видео трафика
local  Useful_cnt = 0;      // Счётчик задержки до экономии трафика
local  Detect_max = fps * 60;    // Задержка до обновления буфера фона при обнаружении
local  Detect_cnt = Detect_max;  // Счётчик "спокойствия" кадра
local  Detect_rep = fps * 45;    // Повторная задержка счётчика "спокойствия"
local  Motion  = 0;      // Направление движения
local  Statistic_out = 0;    // Сколько выходило
local  Statistic_in = 0;      // Сколько входило
local  Statistic_noise = 0;
local  Statistic_detect = 0;
local  Statistic_motion = 0;
local  Statistic_refresh = 0;
function reset(st) {
  Statistic_out = 0;
  Statistic_in = 0;
  Statistic_noise = 0;
  Statistic_detect = 0;
  Statistic_motion = 0;
  Statistic_refresh = 0;
  Beep();
}
function main(st) {
  Status(st.ver + "; Resolution: " + st.w + "x" +  st.h);
  Sleep = (st.ss + 5) % 60;
  if(State("Option", 1))
    start_hh = st.hh, start_mm = 59, show_hh = (start_hh + 1) % 24, show_mm = (start_mm + 1) % 60;
  Statistic_out = State("swExtra", 20);  // Сколько выходило
  Statistic_in = State("swExtra", 21);  // Сколько входило
  Statistic_noise = State("swExtra", 22);
  Statistic_detect = State("swExtra", 23);
  Statistic_motion = State("swExtra", 24);
  Statistic_refresh = State("swExtra", 25);
}
function render(st) {
//  if(st.y > 40 && st.y < 480 - 40) Banner(1.0, 5, 0.0, st.x - 60, st.y - 40, -120, 80);
  if(st.mm == start_mm && st.hh == start_hh) {
    if(st.ss == 0) {
      State("sbExtra", 7, 0x80), State("sbExtra", 19, 0);
    }
    Beep();
    return 1;
  } else
  if(st.mm == show_mm && st.hh == show_hh) {
    if(st.ss >= 15) {
      State("sbExtra", 7, 0xF0), State("sbExtra", 19, 1);
      start_hh = 23, start_mm = 59, show_hh = 0, show_mm = 0;
    } else {
      Beep();
      return 1;
    }
  }
local  n = 0, perc=0, summ=0, subj=0, dirt=0, start=false;
local  gritty = State("sbExtra", 20);        // Чувствительность
local  amount = State("sbExtra", 21);        // Масштабность
  if(!State("Option", 0))
    return Chroma(0.1, 0.0), Refresh_cnt = Refresh_max;
  Chroma(0.3, 0.0);              // Копируем исходный кадр в "запас"
  Chroma(0.0, gritty + 0.1);          // Строим дифференционную Альфа-маску
  if(Refresh_cnt < 1)            // Если буфер фона безнадёжно устарел
    Chroma(0.1, 0.0), Refresh_cnt = Refresh_max;  // * Обновить его и восстановить свежесть фона
  summ = Chroma(0.0, amount,          // Индексируем все "годные" субъекты в кадре
      Useful_cnt > 0 ? 0.3 : 0x3355, 0.3);
  subj = (summ >> 24) & 255;          // Число субъектов в кадре
  dirt = (State("Breaks", 255) >> 24) & 255;    // Число объектов вне зоны полезности  
  perc = (0.0 + ((summ & 0xFFFFFF) * 1000 /      // Процентность масштабности общей
      (st.w * st.h))) / 10.0;        // площади, занимаемой объектами в кадре
  if(subj > 0)              // Обнаружены субъекты в "полезной" зоне?
    start = ((Detect_cnt --) == Detect_max),    // * Уменьшить счётчик "терпения" детектора
    Useful_cnt = Useful_max, Spots(1, 255),    // * Выставить счётчик полезности
    Refresh_cnt --, Beep();          // * Уменьшить уровень "свежести" буфера фона
  else                  // Объекты отсутствуют
    Detect_cnt += Detect_cnt < Detect_max ? 1 : 0,  // * Восполнить уровень "терпения" детектора
    Useful_cnt --;            // * Уменьшить уровень полезности потока
  if(subj == 0 && dirt > 0)          // Обнаруживаются объекты вне полезной зоны?
    Refresh_cnt --;            // * Уменьшить уровень свежести буфера фона
  if(Detect_cnt < 1)            // Уровень "терпения" детектора исчерпан?
    Detect_cnt = Detect_rep,        // * Восполнить "терпение"
    Refresh_cnt = 0,            // * Принудить буфер фона обновиться
    Statistic_detect ++;          // * Считать число "восполнений терпения"
  if(Refresh_cnt == 0)            // Уровень свежести буфера фона исчерпан?
    Statistic_noise += !subj && dirt > 0 ? 1 : 0,  // * Возможно, это простой шум
    Statistic_refresh ++;          // * Считать число обновлений фона
  if(Useful_cnt < 1)            // Полезность кадра исчерпана?
    Useful_cnt = 0;            // * Полностью
  State("sbExtra", 7, !!Useful_cnt ? 0xF0 : 0xE0);  // Скрыть/показать строку бинарного тайм-кода
  if(start) {
    start = Spots(-3, 1);
    if(start == -15)
        Statistic_in ++, Motion = start;
    if(start == -12 || start == -8 || start == -4)
        Statistic_out ++, Motion = start;
  } else
  if(Motion) {
    start = Spots(-3, 1);
    if(Motion == -15 && (start == -12 || start == -8 || start == -4))
      Statistic_motion ++;
    else
    if(start == -15 && (Motion == -12 || Motion == -8 || Motion == -4))
      Statistic_motion ++;
    Motion = 0;
  }
  if(Sleep > 0)
    -- Sleep;
  else
    Status(
      Str("%2d:%02d:%02d.%02d Таймер %2d:%-07.2d", st.hh, st.mm, st.ss, st.SS % 100, start_hh, start_mm),
      Str("Чувствительность:%3d%%", (100 - gritty)),
      Str("Масштаб :%3s%% при %5s%%", "" + perc, "" + ((0.0 + amount) / 10.0)),
      Str("Объектов:%3d #3:%02X", subj, Spots(-3, 1) & 0xFF),
      Str("Вне зоны:%3d", dirt),
      Str(" Свежесть плана  :%3d%%", (Refresh_cnt * 100 / Refresh_max)),
      Str(" Полезность кадра:%3d%%", (Useful_cnt * 100 / Useful_max)),
      Str(" Статичность     :%3d%%", (Detect_cnt * 100 / Detect_max)),
      "Статистика сеанса:",
      "         Снимков :" + Statistic_detect,
      "         Шума    :" + Statistic_refresh,
      "         Помех   :" + Statistic_noise,
      "         Ходьбы  :" + Statistic_motion + " " + Statistic_in+">" + Statistic_out,
          (State("Option", 1) ? "Прозрачность" : "Перекрытие  ") + " X:Y=" + st.x + ":" + st.y
    );
  State("swExtra", 20, Statistic_out);  // Сколько выходило
  State("swExtra", 21, Statistic_in);    // Сколько входило
  State("swExtra", 22, Statistic_noise);
  State("swExtra", 23, Statistic_detect);
  State("swExtra", 24, Statistic_motion);
  State("swExtra", 25, Statistic_refresh);
  return 1;
}